Este estudio en gobierno corporativo aplica técnicas de análisis de panel de datos en diferentes mercados emergentes.
La estructura de la base de datos permite un análisis de panel de datos, pero además debería existir una justificación para la introducción de la dimensión tiempo (a parte de incrementar el tamaño de la muestra).
A priori, la matriz de covarianzas OLS basada en errores iid podría ser inadecuada ya que los errores para una empresa determinada podrían estar correlacionados a lo largo del tiempo.
Descargar el archivo Ownership_data1.zip y abrir el archivo Ownership_data.dta en una carpeta de trabajo.
PANEL vs OLS (efectos fijos vs pooled OLS) xttest0
Primero, asumiendo homocedasticidad, se aplica una prueba LM de Breusch-Pagan (1980) para efectos fijos(*) y la especificación pooled OLS es rechazada debido a la presencia de heterogeneidad no observable. La heterogeneidad no observable se refiere a características no observables específicas a cada empresa individual que son variables aleatorias (omitidas) potencialmente correlacionadas con los regresores.
(*) los efectos fijos y aleatorios de son de la misma "familia"
/*se usa para poner comentarios en el do-file*/
Ejecutar los siguientes comandos (i.e. en un do-file)
cd: C:\....\Downloads /* ubica el archivo de data, donde esté */
cls /* pantalla en blanco */
clear /* limpia la memoria */
use Ownership_data /* abre el archivo de data */
/* el comando quietly es opcional, suprime el output del comando reg. pruebe eliminándolo, para ver el output */
quietly reg tobinq rat1 cfcon1 top2_3 chile colombia peru venezuela y2001 y2002 y2003 y2004 y2005 y2006 lsize volatility leverage
/* el comando reg produce la regresión ordinaria de mínimos cuadrados */
estimates store OLS /* guarda el output en la variable OLS */
quietly xtreg tobinq rat1 cfcon1 top2_3 chile colombia peru venezuela y2001 y2002 y2003 y2004 y2005 y2006 lsize volatility leverage, re i(idnum)
/* el comando xtreg produce la regresión de efectos aleatorios con la opción re */
estimates store RE /* guarda el output en la variable RE */
xttest0 /* LM test */
return list /* muestra cómo se llaman las variables donde se almacena temporalmente el output del LM test */
local LM : display %5.2f `r(lm)'
local P : display %4.3f `r(p)'
/* asigna variables permanentes al output del LM test */Las alternativas que quedan para estimar los coeficientes de las regresiones son las especificaciones por efectos fijos o por efectos aleatorios.
La especificación por efectos fijos, permite la inclusión de características específicas (no observables) a cada empresa en la estimación de los coeficientes de regresión, así como en el cálculo de los errores estándar. Permite que los errores sean heterocedásticos y autocorrelacionados en cada empresa, pero no correlacionados a través de diferentes empresas. La especificación por efectos fijos asume que las características no observables específicas a cada empresa no están correlacionadas con ningún regresor (lo cual sería un supuesto fuerte), mientras que la especificación por efectos aleatorios permite alguna forma no especificada de correlación. Sin embargo, con la especificación por efectos fijos, los coeficientes de los regresores constantes en el tiempo no están identificados.
Efectos fijos vs Efectos aleatorios Hausman test
Segundo, habiendo confirmado la presencia de heterogeneidad no observable, se usa una prueba de Hausman (1978) para distinguir entre efectos aleatorios y efectos fijos. Bajo la hipótesis nula de la prueba, ambos coeficientes estimados por efectos fijos y por efectos aleatorios son consistentes, pero los coeficientes estimados por efectos aleatorios son más eficientes, por lo cual toda diferencia en la varianza estimada se debe a errores de muestreo.
quietly xtreg tobinq rat1 cfcon1 top2_3 chile colombia peru venezuela y2001 y2002 y2003 y2004 y2005 y2006 lsize volatility leverage, fe i(idnum)
/* el comando xtreg produce la regresión de efectos aleatorios con la opción fe */
estimates store FE /* guarda el output en la variable FE */
hausman FE RE /* Hausman test, el orden es importante */
return list /* muestra cómo se llaman las variables donde se almacena temporalmente el output del Hausman test */
local HAU : display %5.2f `r(chi2)'
local DF : display %2.0f `r(df)'
local PHAU : display %4.3f `r(p)'
/* asigna variables permanentes al output del Hausman test */
estimates table OLS RE FE, keep (rat1 cfcon1 top2_3 lsize volatility leverage _cons) b(%9.3f) star stats(r2 r2_a N ) title("Panel data: tobinq es la variable dependiente. Para FE y RE el R2 sin interpretación.")
/* produce una tabla resumen de las 3 regresiones */ El estadístico sigue una distribución de CHI2 con grados de libertad igual al número de regresores que sí varían en el tiempo. Bajo la hipótesis alternativa, los coeficientes estimados por efectos aleatorios son inconsistentes. Un estadístico “grande” para la prueba resulta en el rechazo de la hipótesis nula para los niveles de significancia dados (grande con respecto al valor de la tabla).
En este caso, los resultados de la prueba NO rechazan la especificación por efectos aleatorios.
Los siguientes comandos permiten obtener los resultado formateado en MS-Word.
putdocx clear
putdocx begin, pagenum(decimal) header(encabezado) footer(npage) margin(left,0.5) margin(right,0.5) pagesize(A4) landscape
putdocx paragraph, style(Title)
putdocx text ("Ownership, Panel Regression.")
putdocx paragraph, style(Subtitle)
putdocx text ("variable dependiente tobinq")
putdocx paragraph, style(Subtitle)
putdocx text ("variable independiente de interés rat1")
putdocx table tblD1 = etable
putdocx table tblD1(.,1), border(right, nil)
putdocx table tblD1(1,1) = ("")
putdocx paragraph, style(Heading4)
putdocx text ("(*) p < 0.05, (**) p < 0.01, (***) p < 0.001. Para FE y RE el R2 no tiene ninguna interpretación.")
putdocx paragraph, style(Heading4)
putdocx text ("Breusch-Pagan (1980) test:")
putdocx paragraph
putdocx text ("LM_CH `LM'; LM_p `P'")
putdocx paragraph
putdocx text ("Se rechaza la especificación pooled OLS cuando LM_p < 0.05")
putdocx paragraph, style(Heading4)
putdocx text ("Hausman (1978) test:")
putdocx paragraph
putdocx text ("HAU_CH `HAU'; DF `DF'; HAU_p `PHAU'")
putdocx paragraph
putdocx text ("Se rechaza la especificación RE cuando HAU_p < 0.05. No es el caso")
putdocx save Panel_data_Ownership, replace ¡El resultado debe verse como en la figura!
Guardar y cerrar el archivo.
Por favor, me comentan si les salió, también me comentan si hay algún error (de tipeo).😊
Si algún archivo no descarga, no duden en solicitarlo por e-mail.
Por favor citar así:
"Cueto, Diego C. (19 de abril de 2022). Panel data en STATA. [Mensaje en un blog].
Recuperado de https://dcueto9.wixsite.com/website/post/paneldataenstata"
¡Puedes compartir en las redes sociales!😉
Comments